Tixraac dhamaystiran ee ereyada (keywords) Soplang (door, madoor, haddii, kuceli, hawl, celi, qaab, fasax, keen, iwm).

Soplang Keywords Reference

Dukumeentigani waxa uu soo koobayaa ereyada (keywords) ee Soplang, macnahooda, u dhigmaha Ingiriisiga, iyo tusaalooyin isticmaal. Ereyadan looma isticmaali karo magac doorsoome ama hawl.

Variable Declaration Keywords

Keyword	Meaning	English Equivalent	Example
`door`	Dynamic variable declaration	`var/let`	`door magac = "Sharafdin"`
`madoor`	Constant variable declaration	`const`	`madoor PI = 3.14159`
`abn`	Integer type	`int`	`abn da = 25`
`jajab`	Decimal/float type	`float/double`	`jajab qiimo = 3.14`
`qoraal`	String type	`string`	`qoraal magac = "Sharafdin"`
`bool`	Boolean type	`bool`	`bool waaRun = run`
`walax`	Object type	`object`	`walax qof = { magac: "Sharafdin" }`
`teed`	List/array type	`array`	`teed numbers = [1, 2, 3]`

abn, jajab, qoraal, bool, teed, iyo walax waxay sidoo kale yihiin hawlo beddel-nooc ah (abn(4.9), qoraal(25)). Eeg Built-in Functions.

Control Flow Keywords

Keyword	Meaning	English Equivalent	Example
`haddii`	If statement	`if`	`haddii (x > 10) { qor("Weyn") }`
`haddii_kale`	Else if statement	`else if`	`haddii_kale (x == 10) { qor("Dhexe") }`
`ugudambeyn`	Else / default case	`else` / `default`	`ugudambeyn { qor("Yar") }`
`dooro`	Switch statement	`switch`	`dooro (x) { xaalad 1 { qor("Hal") } }`
`xaalad`	Case clause	`case`	`xaalad "A" { qor("Case A") }`
`kuceli`	For loop (inclusive range)	`for`	`kuceli (i 1 ilaa 5) { qor(i) }`
`ilaa`	Loop range end (only inside `kuceli`)	`to`	`kuceli (i 1 ilaa 5) { qor(i) }`
`::`	Loop step	`step`	`kuceli (i 1 ilaa 10 :: 2) { qor(i) }`
`intay`	While loop	`while`	`intay (x < 5) { qor(x) }`
`jooji`	Break statement	`break`	`haddii (x == 3) { jooji }`
`soco`	Continue statement	`continue`	`haddii (x == 3) { soco }`

Function Keywords

Keyword	Meaning	English Equivalent	Example
`hawl`	Function declaration	`function`	`hawl isuGee(a, b) { celi a + b }`
`celi`	Return statement	`return`	`celi x * 2`

Class Keywords

Keyword	Meaning	English Equivalent	Example
`qaab`	Class definition	`class`	`qaab Bisad { ... }`
`dhaxal`	Inherit from a parent class	`extends`	`qaab Bisad dhaxal Xayawaan { ... }`
`cusub`	Create a new instance	`new`	`door b = cusub Bisad("Mia")`
`nafta`	The current instance	`this` / `self`	`nafta.magac = magac`
`dhaw`	Constructor method name (called by `cusub`)	`constructor`	`hawl dhaw(magac) { nafta.magac = magac }`

dhaw ma aha keyword la xafiday — waa magaca hawsha constructor-ka. Eeg Classes.

Error Handling and Module Keywords

Keyword	Meaning	English Equivalent	Example
`fasax`	Protected (try) block	`try`	`fasax { ... } qabo (k) { ... }`
`qabo`	Catch block with error variable	`catch`	`qabo (khalad) { qor(khalad) }`
`keen`	Import another `.sop` file	`import`	`keen "utils.sop"`

Eeg Error Handling iyo Modules.

Special Values

Somali Value	English Equivalent	Description	Example
`run`	`true`	Boolean true value	`haddii (run) { ... }`
`been`	`false`	Boolean false value	`haddii (!been) { ... }`
`null`	`null`	No value — prints as `maran`, and `nooc(null)` is `"maran"`	`door val = null`

Operators

Somali Operator	English Equivalent	Description	Example
`+`	`+`	Addition / string concatenation	`x = a + b`
`-`	`-`	Subtraction / negation	`x = a - b`
`*`	`*`	Multiplication	`x = a * b`
`/`	`/`	Division	`x = a / b`
`%`	`%`	Modulo	`x = a % b`
`==`	`==`	Equal to	`haddii (a == b) {...}`
`!=`	`!=`	Not equal to	`haddii (a != b) {...}`
`>`	`>`	Greater than	`haddii (a > b) {...}`
`<`	`<`	Less than	`haddii (a < b) {...}`
`>=`	`>=`	Greater than or equal to	`haddii (a >= b) {...}`
`<=`	`<=`	Less than or equal to	`haddii (a <= b) {...}`
`&&`	`&&`	Logical AND	`haddii (a && b) {...}`
`\|\|`	`\|\|`	Logical OR	`haddii (a \|\| b) {...}`
`!`	`!`	Logical NOT	`haddii (!a) {...}`

&& iyo || waa isku heer (bidix ilaa midig) — isticmaal qaansooyin () marka aad isku darayso. Eeg Operators.

Quick Examples

keywords_quick_examples.sop

keywords_quick_examples.sop

// Variables
door magac = "Sharafdin"
madoor PI = 3.14159
abn da = 25
jajab qiimo = 3.14
qoraal qora = "Salaan"
bool sax = run
teed numbers = [1, 2, 3]
walax qof = { magac: "Ayaan" }
door wax = null

// Control flow
haddii (da >= 18) { qor("Qof weyn") } ugudambeyn { qor("Ilmo") }

dooro (qora) {
xaalad "Salaan" { qor("Hello!") }
ugudambeyn { qor("Unknown") }
}

kuceli (i 1 ilaa 5 :: 2) { qor(i) }

abn x = 1
intay (x < 3) {
qor(x)
x = x + 1
}

// Functions
hawl isuGee(a, b) { celi a + b }
qor(isuGee(2, 3))

// Classes
qaab Qof {
hawl dhaw(magac) { nafta.magac = magac }
hawl salaam() { celi "Salaan, " + nafta.magac }
}
door q = cusub Qof("Aamina")
qor(q.salaam())

// Error handling
fasax {
qor(10 / 0)
} qabo (khalad) {
qor("Khalad: " + khalad)
}

Soplang Keywords Reference

On this page